【VBA】ExcelからADOでAccessのデータを削除する

2018年08月24日 · 3 分で読了 · Access VBA

概要

ExcelからADOでAccessのデータを削除してみます。

今回はデータの物理削除ではなくYes/No型を利用した論理削除になります。

Accessファイルの概要

Accessファイルは以下のパスに置かれています。
C:\access-delete-test\MenuData.accdb

Accessにはテーブル「T_メニュー」があります。
T_メニューにはメニューデータが記録されています。

テーブルは以下のフィールドで構成されています。

フィールド名	データ型
ID	オートナンバー型
メニュー名	短いテキスト
値段	数値型
データ新規登録者	短いテキスト
データ新規登録日	日付/時刻型
データ更新者	短いテキスト
データ更新日	日付/時刻型
削除フラグ	Yes/No型書式はTrue/False

削除フラグがTrueになっているものを、削除データとみなします。

削除フォーム

今回はIDが7のピザをCさんが削除するとしてみます。

データベースからメニューを削除したいのでデータ削除用のフォームをシートに用意します。
シート名はDeleteDataとします。

削除したいメニューのIDとデータ削除者の名前を入力します。

A3セルに削除したいメニューのIDを入力します。
B3セルにデータ削除者を入力します。

削除ボタンを押すとデータを削除します。

データ削除のVBAコード

参照設定

ExcelからADOを利用してAccessのデータを更新するには
参照設定を行う必要があります。
参照設定の方法は以下をご覧ください

https://kazusa-pg.com/vba-references/

参照設定を起動してMicrosoft ActiveX Data Objects 6.1 Libraryにチェックを入れます。

データを削除するコードは以下になります。

 1Option Explicit
 2Sub deleteMenu()
 3  
 4  Dim returnVal As Long
 5  returnVal = MsgBox("メニューを削除しますか？", vbYesNo + vbQuestion, "確認")
 6  If returnVal = vbNo Then Exit Sub
 7
 8  Dim deleteSht As Worksheet
 9  Set deleteSht = ThisWorkbook.Worksheets("DeleteData")
10  
11  Dim adoCON As New ADODB.Connection
12  adoCON.ConnectionString = "provider=Microsoft.ACE.OLEDB.12.0;" & _
13                  "Data Source=" & "C:\access-delete-test\MenuData.accdb" & ";"
14  adoCON.Open
15  
16  Dim id As Long
17  Dim personName As String
18  
19  id = deleteSht.Range("A3")
20  personName = deleteSht.Range("B3")
21  
22  Dim adoRS  As New ADODB.Recordset
23  adoRS.Open "SELECT * FROM T_メニュー WHERE ID = " & id, adoCON, adOpenDynamic, adLockPessimistic
24  adoRS!データ更新者 = personName
25  adoRS!データ更新日 = Now()
26  adoRS!削除フラグ = True
27  adoRS.Update
28
29  adoRS.Close
30  adoCON.Close
31  
32  Set deleteSht = Nothing
33  Set adoCON = Nothing
34  Set adoRS = Nothing
35  
36  MsgBox "メニューを削除しました", vbInformation, "削除完了"
37  
38End Sub